#!/usr/bin/pike
/*
 * tiler.pike
 *
 * Tiles NxM different pngs into a single png
 *
 * History:
 *       1/07/2019 Creation
 *	 5/11/2019 Fix erroneous 1-pixel border around every tile
 *
 * Author: Dario Rodriguez dario@softhome.net
 * This program is distributed under the terms of the GNU GPL v2.1+
 */

int
main(int argc, array(string) argv)
{
        int a4w,a4h;
	int maxx,maxy;
        int px,py;
        string destfilename;
        int total;
        Image.Image img,result;
        if(argc<4 || (argc>1 && argv[1]=="--help")) {
                Stdio.werror("Syntax:  "+argv[0]+" <width_in_tiles> <height_in_tiles> <file1.png> [<file2.png> [...]] <destfile.png>\n");
                Stdio.werror("Example: "+argv[0]+" 3 2 file1.png file2.png file3.png file4.png file5.png file6.png dest.png\n");
                Stdio.werror("Example result: dest.png\n");
                return(1);
        }
        a4w=(int)argv[1];
        a4h=(int)argv[2];
        destfilename=argv[sizeof(argv)-1];
	array(string) infiles=argv[3..sizeof(argv)-2];
	maxx=maxy=1;
	write("* Calculating tile size\n");
	foreach(infiles, string f) {
		img=Image.load(f);
		if(img->xsize()>maxx)
			maxx=img->xsize();
		if(img->ysize()>maxy)
			maxy=img->ysize();
	}
	result=Image.Image(maxx*a4w,maxy*a4h,255,255,255);
	px=py=0;
	total=0;
	foreach(infiles, string f) {
        	write("* Processing "+f+"...\n");
		img=Image.load(f);
		result->paste(img,px*(maxx),py*(maxy));
		px++;
		if(px>=a4w) {
			px=0;
			py++;
		}
		total++;
	}
        write("* Writing "+destfilename+"...\n");
        Stdio.write_file(destfilename,Image.PNG.encode(result));
        write("tiled "+total+" images into "+destfilename+". Process finished.\n");
        return(0);
}